[Coco] Shamus... copy protected?

[Darren A.]

Okay, it seems that the "less than" symbol immediately followed by a digit was fouling up the mail client. I think (hope) the listing below will come through correctly:


1 CLEAR0:PMODE0,1:PCLEAR1:IFPEEK(2395)>0ANDPEEK(&HC005)=&H6C ANDPEEK(116)< 127THEN56
2 IFPEEK(116)=127THENCLEAR50,9727:BP=38:BT=5 ELSECLEAR50,7167:BP=28:BT=2
3 CLS:PRINT"     - THE SANDS OF EGYPT -"
4 PRINT:PRINT"THIS UTILITY ALLOWS YOU TO MAKE A BACKUP COPY OF THE PROGRAM","DISK. THE BACKUP WILL BE","COPY-PROTECTED JUST LIKE THE","ORIGINAL.":PRINT
5 PRINT"A DUAL DRIVE SYSTEM IS NOT","REQUIRED, BUT USING A SINGLE","DRIVE WILL REQUIRE many SWAPS.":PRINT
6 PRINT"CONTINUE..."
7 IFINKEY$=""THEN7
8 DK=PEEK(&HC004)*256+PEEK(&HC005):IFDK<>&HD75F ANDDK<>&HD66C THENCLS:PRINT"YOUR DISK BASIC ROM IS NOT","RECOGNIZED.":END
9 CLS:PRINT"TO BE SAFE, YOU SHOULD PLACE A","WRITE-PROTECT TAB ON THE SOURCE DISK BEFORE PROCEEDING.":PRINT
10 INPUT"SOURCE DRIVE NUMBER";SD:IFSD< 0ORSD>3THEN10
11 INPUT"  DESTINATION DRIVE";DD:IFDD< 0ORDD>3THEN11
12 IFSD=DD THEN14ELSECLS:PRINT"INSERT SOURCE AND DESTINATION","DISKETTES AND PRESS ENTER"
13 IFINKEY$<>CHR$(13)THEN13
14 ST=0:DT=0:KT=17:KS=0
15 TD$="SOURCE":GOSUB29:CLS
16 OP=2:DR=SD:TR=ST:GOSUB20:ST=TR
17 TD$="DESTINATION":GOSUB29
18 OP=3:DR=DD:TR=DT:GOSUB20:DT=ST
19 IFKS<>0THENPRINT"BACKUP COMPLETE!":GOTO55 ELSEIFST< 35THEN15 ELSE33
20 TC=BT:DP=BP:POKE234,OP:POKE235,DR:POKE239,0
21 IFTR=KT THENTR=TR+1
22 IFOP=2THENPRINT at 0,"READING";ELSEPRINT at 32,"WRITING";
23 IFTR=17THENPRINT" DIRECTORY"ELSEPRINT" TRACK"TR
24 POKE236,TR:FORS=1TO18
25 IFS=KS THENS=18:GOTO28
26 POKE237,S:POKE238,DP
27 GOSUB53:DP=DP+1
28 NEXTS:TR=TR+1:TC=TC-1:IFTC=0ORTR>34THENRETURNELSE21
29 IFSD<>DD THENRETURN
30 CLS:PRINT"INSERT "TD$" DISK AND","PRESS ENTER."
31 IFINKEY$<>CHR$(13)THEN31
32 CLS:RETURN
33 PRINT"COPY-PROTECTING..."
34 FORA=0TO17:READS:POKE&H700+A,S:NEXTA
35 A=BP*256:GOSUB42
36 IFDK=&HD66C THENREADOP$,OP$,OP$:GOSUB42ELSEGOSUB42:READOP$,OP$,OP$
37 A=&H1DA:GOSUB42
38 POKE236,KT:EXEC(BP*256)
39 POKE234,2:POKE235,DD:POKE236,KT:POKE237,1:POKE238,6
40 GOSUB53:EXEC&H1DA
41 BT=1:ST=KT:DT=KT:KT=0:KS=16:GOTO15
42 READOP$:IFOP$="X"THENRETURNELSEPOKEA,VAL("&H"+OP$):A=A+1:GOTO42
43 DATA 1,12,5,99,9,2,13,6,17,10,3,14,7,18,11,4,15,8
44 DATA 30,8C,FD,BF,07,20,7E,X
45 DATA D6,94,X
46 DATA D5,A7,X
47 DATA 1A,50,30,8D,00,25,BF,09,83
48 DATA 10,8E,FF,4B,BE,07,20,B6,FF,48
49 DATA 86,FF,B7,09,82,C6,F4,F7,FF,48
50 DATA B6,09,86,8A,80,B7,FF,40,E6,80
51 DATA E7,A4,20,FA,B6,FF,48,84,44
52 DATA 1C,AF,97,F0,39,X
53 EXECDK:IFPEEK(240)=0THENRETURN
54 PRINT"I/O ERROR...BACKUP ABORTED!":SOUND1,5
55 END
56 PRINT"PLEASE TYPE RUN AGAIN.":FILES0,0




_________________________________________________________________
The best games are on Xbox 360.  Click here for a special offer on an Xbox 360 Console.
http://www.xbox.com/en-US/hardware/wheretobuy/